rich           ::= content
content        ::= block | inline
block          ::= group
                 | paragraph
                 | unordered-list
                 | ordered-list
                 | code
                 | section
                 | image
                 | quote
group          ::= (content*)
paragraph      ::= (:p inline*)
unordered-list ::= (:ul group*)
               --- Wherein each group represents a list item
ordered-list   ::= (:ol group*)
               --- Wherein each group represents a list item
code           ::= (:code string string)
               --- The first string designates the language (and thus syntax highlighting rules) for the code in the second string.
section        ::= (:section (integer inline*) content*)
               --- The integer designates the depth of the header, and its accompanying inline segments the header content.
image          ::= (:image target)
quote          ::= (:quote string content*)
               --- The string designating the quote author
inline         ::= bold
                 | italic
                 | underline
                 | strikethrough
                 | monospace
                 | subtext
                 | supertext
                 | link
                 | color
                 | string
bold           ::= (:b inline*)
italic         ::= (:i inline*)
underline      ::= (:u inline*)
strikethrough  ::= (:s inline*)
monospace      ::= (:m inline*)
subtext        ::= (:sub inline*)
supertext      ::= (:sup inline*)
link           ::= (:link target inline*)
color          ::= (:color rgb inline*)
rgb            ::= (float float float)
               --- An sRGB additive colour triplet, with 0 meaning no contribution and 1 meaning full contribution to the respective channel.
target         ::= string
               --- An URL encoded in the string.