(defclass resettable-class (standard-class) ())

(defmethod c2mop:validate-superclass ((class resettable-class)
                                      (superclass standard-class))
  t)

(defun reset-instance (instance &rest initargs)
  (let* ((slots (c2mop:class-slots (class-of instance)))
         (names (mapcar #'c2mop:slot-definition-name slots)))
    (mapcar (lambda (slot) (slot-makunbound instance slot)) names)
    (apply #'initialize-instance instance initargs)))

(defmethod initialize-instance :after ((class resettable-class) &key)
  (let* ((method-lambda (c2mop:make-method-lambda
                         #'reinitialize-instance
                         (c2mop:class-prototype (find-class 'standard-method))
                         '(lambda (instance &rest initargs)
                           (apply #'reset-instance instance initargs))
                         nil))
         (method (make-instance 'standard-method
                                :qualifiers '()
                                :specializers (list class)
                                :lambda-list '(instance &rest initargs)
                                :function (compile nil method-lambda))))
    (add-method #'reinitialize-instance method)))

(defclass thing ()
  ((foo :initarg :foo :initform (random 42))
   (bar :initarg :bar :initform (random 42))
   (baz :initarg :baz :initform (random 42)))
  (:metaclass resettable-class))



CL-USER> (defparameter *thing* (make-instance 'thing))
*THING*

CL-USER> (describe *thing*)
#<THING {1010E7C423}>
  [standard-object]

Slots with :INSTANCE allocation:
  FOO                            = 26
  BAR                            = 31
  BAZ                            = 16
; No value

CL-USER> (reinitialize-instance *thing* :bar 2222)
#<THING {1010E7C423}>

CL-USER> (describe *thing*)
#<THING {1010E7C423}>
  [standard-object]

Slots with :INSTANCE allocation:
  FOO                            = 39
  BAR                            = 2222
  BAZ                            = 36
; No value